Monkeybot Source Listing

This is the source code for Monkeybot which you are free to use as a template for writing your own computer opponents. It has been written in Delphi 6 and should be compatible with most other versions. These files are available online for download here.

Monkeybot.dpr

library Monkeybot;

{$R Monkeybot.res}

uses
  Classes;

type
  TCellValue = 0..2;
  TCell = record
    Value: TCellValue;
    PlayIdx: Integer;
  end;
  TCells = array[1..4,1..4,1..4] of TCell;
  {The cube is a TCells object. TCells is a three-dimensional array (4x4x4) of
  TCell. Each cell has a value of 0 (empty), 1 (move by P1) or 2 (move by P2).}
  TCoord = record
    x,y,z: 1..4;
  end;

function Coord(x,y,z: Integer): TCoord;
begin
  Result.x := x;
  Result.y := y;
  Result.z := z;
end;

function GetInfo(Info: Integer): PChar; export;
begin
  {Returns information about your player}
  case Info of
    0: Result := 'Monkeybot'; {Name}
    1: Result := 'Monkeybot doesn''t know how to play the game.'; {Description}
    2: Result := '1.0'; {Version}
    3: Result := 'Yann Cluchey'; {Author}
    4: Result := 'http://www.cluchey.com/'; {Homepage}
  else Result := '';
  end;
end;

procedure OnNewGame(Opponents: PChar; Cube: TCells; PlayerNum: TCellValue);
                   export;
begin
  {This gets called every time a new game is started. The DLL is kept in memory
  between games, giving you the possibility to adjust your tactics depending on
  previous games.
  ò Opponents: PChar; - Your opponent's name (Legacy).
  ò Cube: TCells; - The contents of the cube. Empty, unless the user loads a
    saved game.
  ò PlayerNum: TCellValue; - Your player number. Either 1 or 2.}
end;

procedure OnMove(APos: TCoord; Value: TCellValue; Cube: TCells;
                 PlayerNum: TCellValue); export;
begin
  {(Legacy) Called every time a move is made. (Including by you).
  ò APos: TCoord; - Last played coordinate.
  ò Value: TCells; - The value (= player number), either 1 or 2.
  ò Cube: TCells; - The contents of the cube.
  ò PlayerNum: TCellValue; - Your player number.}
end;

function Move(Cube: TCells; PlayerNum: TCellValue): TCoord; export;
var
  x,y,z: Integer;
  List: array of TCoord;
begin
  {Called when it's your turn to move.
  ò Cube: TCells; - The contents of the cube.
  ò PlayerNum: TCellValue; - Your player number.
  Returns a TCoord - the coordinate you would like to play.}

  {Monkeybot is a stupid opponent. It determines which cells are free and
  chooses one at random.}

  SetLength(List,0);
  for x := 1 to 4 do
  begin
    for y := 1 to 4 do
    begin
      for z := 1 to 4 do
      begin
        if Cube[x,y,z].Value = 0 then
        begin
          SetLength(List,High(List)+2);
          List[High(List)].x := x;
          List[High(List)].y := y;
          List[High(List)].z := z;
        end;
      end;
    end;
  end;

  Randomize;
  x := Random(High(List)+1);
  Result := Coord(List[x].x,List[x].y,List[x].z);

end;

exports
  GetInfo,
  OnNewGame,
  OnMove,
  Move;

begin
end.

Tip: To make development more convenient, set the output directory to that of 3D 4-in-a-Row and the host application to 3d4r50.exe.

Monkeybot.rc

1 Bitmap Monkeybot1.bmp
2 Bitmap Monkeybot2.bmp

These bitmaps are the player glyphs displayed in the game. Bitmap 1 is the player 1 glyph and bitmap 2 is the player 2 glyph. To build Monkeybot.res use Borland's Resource Compiler from the command line. Type this: "BRCC32 Monkeybot"

Final Words

If you create a computer opponent, submit it and it will be made available for download on the website. If you have any questions, feel free to contact me.